大众计算机学习网欢迎诸位!收藏本站注 册登 陆
常用教程:基础知识网络知识操作系统WPS网页制作数据库算法网页成功之路网络安全最新技术古典mid流行midmid背景下载中心
您现在的位置:首页 > 教程 > 文章页

提取Excel单元格字符串中连续数字的一种方法

Admin | 2008-7-20 9:58:10 | ReadNums | 18265 | 标签 Excel教程 | 打印本页
     

  ①问题引入

  如何提取字母数字字符串的数字部分。例如:如果单元格 A1 包含的是字符串“abc123”,则将值 123 返回单元格 B1 中。

  ②解决方案

  此解决方案的基本原理是搜索并返回字母数字字符串中的第一个数字,然后只返回其后的数字。

  ③算法

  此解决方案包括创建公式以完成下列任务:

  1、将字母数字字符串分解为单独的字符。
  2、确定分解后的字符串中是否有数字。
  3、确定数字在字母数字字符串中的位置。
  4、计算字母数字字符串中数字的数量。

  我们将分别考虑这些任务,然后将各公式整合在一起以得到最终结果。

  将字母数字字符串分解为单独的字符

  请在此使用 MID 函数。MID 可以根据所指定的字符的数量,从所指定的位置开始,从文本字符串中返回特定数量的字符。此函数的语法是:

  MID(text,start_num,num_chars)

  Text  文本字符串包含的是要提取的字符。
  Start_num  要从文本中提取的第一个字符串的位置。文本中第一个字符占据   start_num 1,以此类推。
  Num_chars  指定要 MID 从文本中返回的字符数量。

  对于我们的示例,公式为:

  =MID(A1,ROW($1:$9),1)

  此公式可以分解字母数字字符串,并且实际上会将字符置于工作表的不同行内。例如,对于字母数字字符串 abc123,其所有 6 个字符都将被分开。

   注释   可将数值 9 适当增大为任何更大的数值,以适应更长的字符串。在此示例中,最大字符串长度为 9。

  值得一提的是,字符串分解之后,“1”、“2”和“3”将被看作文本而不是数字。要将存储为文本的数字转换成数字,请用 1 乘以此公式,例如:

  =1*MID(A1,ROW($1:$9),1)

  确定分解后的字符串中是否有数字

  在此我们将使用 ISNUMBER 函数,此函数可以确定字母数字字符串中是否有数字。公式现在变成了:

  =ISNUMBER(1*MID(A1,ROW($1:$9),1))

  如果字符串中有数字,则结果将为 TRUE,否则结果将为 FALSE。

  确定数字在字母数字字符串中的位置

  现在我们将通过在上一段中提到的分解后的字符串的结果中查找 TRUE 值来确定数字的位置。在此我们将使用 MATCH 函数。经过修改的公式现在变为:

  =MATCH(TRUE,ISNUMBER(1*MID(A1,ROW($1:$9),1)),0)

  要点 必须通过按 Ctrl+Shift+Enter 将此公式作为数组进行输入。

  如果字符串是 abc123,则此公式产生的结果将是 4,这就是字母数字字符串中第一个数字字符的位置。

  计算字母数字字符串中数字的数量

  现在的任务是计算字符串中数字的数量,以确定返回字母数字字符串中第一个数字之后要返回的字符。

  如上所述,可通过用 1 与其相乘,将字母数字字符串中存储为文本的数字转换成数字。例如, =1*MID(A1,ROW($1:$9),1)

  将存储为文本的数字转换成数字之后,可以通过使用 COUNT 函数对其进行计数。可通过输入以下公式计算数字的数量:

  =COUNT(1*MID(A1,ROW($1:$9),1))

  整合各公式

  现在我们将使用 MID 函数把此公式的各部分整合在一起,如以下示例所示。

  =MID(A1,MATCH(TRUE,ISNUMBER(1*MID(A1,ROW($1:$9),1)),0),COUNT(1*MID(A1,ROW($1:$9),1)))

  从本质上说,此问题可陈述为:确定第一个数字在字母数字字符串(在单元格 A1 中)中的位置。返回此数字及其后的数字。

  要将得到的字符转换成数字,请用 1 乘此公式。虽然对此并不严格要求,但如果要对结果执行数学运算,则应该如此操作。下面是要输入单元格 B1 中的最终公式:

  =1*MID(A1,MATCH(TRUE,ISNUMBER(1*MID(A1,ROW($1:$9),1)),0),COUNT(1*MID(A1,ROW($1:$9),1)))

  注意:  必须通过按Ctrl+Shift+Enter将这些公式作为数组进行输入


问题未解决:在线咨询我要在线咨询问题

网友评论

(访客)
内容实用原创,讲得很好。
20xx年x月x日
(站长)
有问题请在线咨询。
20xx年x月x日